RDforum.free.fr/Cast3M   Index du Forum
Site Web Cast3M
RDforum.free.fr/Cast3M
Forum d'entraide des utilisateurs de Cast3M
Répondre au sujet
Problème pour imposer un déplacement
ludovic


Inscrit le: 11 Oct 2010
Messages: 3
Répondre en citant
Bonjour à toutes et à tous,

Je suis doctorant et je dois modéliser un capteur composé d'une lame fine en demi-cercle de 2mm d'épaisseur et 90 de diamètre. Il s'agit d'un calcul tout simple d'élasticité linéaire isotrope.
Le maillage ne m'a posé aucun problème, j'ai crée deux demi-cercles de diamètre 90 et 88 mm reliés entre eux à leurs extrêmités par deux lignes.
J'impose les conditions initiales suivantes : UX et UY bloqués sur la première ligne. UY bloqué sur la deuxième.
Le problème c'est que je dois imposé un déplacement dans la direction X horizontale sur la deuxième ligne (ou un des points de la deuxième ligne, j'ai essayé les deux). La fonction DEPI nécessite que je bloque d'abord le déplacement en UX comme une condition initiale classique.
Le problème c'est que lorsque je lance le calcul, cast3m me renvoie toujours un vecteur déplacement nul et donc la déformée est nulle.
Le calcul marche si j'impose une force plutôt qu'un déplacement ce qui me fait penser que le problème ne vient pas du maillage.

Si quelqu'un peut m'aider ce serait vraiment sympa.

Merci.

Voilà les (quelques) lignes que j'ai pu écrire. (Je joint également le fichier .dgibi)

****************************************
*Definition du problème
****************************************
*
TITRE 'Capteur de Déformations Radiales';
*
OPTI DIME 2 ELEM QUA4;
OPTI MODE PLAN CONT;
*
uimposé = 0.01;
ep = 0.002;
ec = 0.09;
l1 = 0.02;
E1 = 220000000000;
nu1 = 0.285;
*
*
****************************************
*Definition de la géométrie du problème
****************************************
*
*
P1 = 0. 0.;
P2 = ep 0.;
P3 = (ec/2.) 0.;
P4 = (ec-ep) 0.;
P5 = ec 0.;
*
*
Nelt1 = 4;
Nelt2 = 80;
*
L1 = P1 DROIT Nelt1 P2;
L2 = P4 DROIT Nelt1 P5;
C1 = LIGN Nelt2 P3 P5 180 'ROTA';
C2 = LIGN Nelt2 P3 P4 180 'ROTA';
*
cont1 = C1 ET L2 ET C2 ET L1;
TRACE cont1;
*
ELIM 0.0001 cont1;
Mail1 = DALL C1 L2 C2 L1 'PLAN';
*
TRACE Mail1;
*
*FIN;
*
*
*****************************************
*Modele et Materiau
*****************************************
*
mo1 = MODE Mail1 MECANIQUE ELASTIQUE;
ma1 = MATE mo1 'YOUN' E1 'NU' nu1;
*
*
*****************************************
*Conditions initiales
*****************************************
*
CLL1 = BLOQ L1 UX UY;
CLL2 = BLOQ L2 UX UY;
*
cdi1 = BLOQ L2 UX;
di1 = DEPI cdi1 -0.01;
*
CL1 = CLL1 ET CLL2;
*
*
*F1 = FORCE (-100. 0.) P4;
*
*****************************************
*Resolution
*****************************************
*
Rig1 = RIGI mo1 ma1;
Ri1 = Rig1 ET CL1;
*
depl1 = RESO Ri1 di1;
*
*
*****************************************
*Post-traitement
*****************************************
*
*
*LIST Rig1;
LIST depl1;
Def0=DEFO Mail1 depl1 0. BLANC;
Def1=DEFO Mail1 depl1 ROUGE;
TITRE 'Déformée' ;
TRAC (Def0 ET Def1);
*
*
FIN;



capteur_v4.dgibi
 Description:

Télécharger
 Nom du fichier:  capteur_v4.dgibi
 Taille du fichier:  1.65 Ko
 Téléchargé:  326 fois

Voir le profil de l'utilisateurEnvoyer un message privéEnvoyer un e-mail
lguenhael
Administrateur

Inscrit le: 25 Nov 2006
Messages: 146
Localisation: Laboratoire Roberval - UTC
Répondre en citant
Bonjour,

Il faut ajouter cdi1 à CL1. Par ailleurs, il faut enlever UX dans CLL2 puisque cdi1 s'en charge.

Cordialement.
Voir le profil de l'utilisateurEnvoyer un message privéEnvoyer un e-mail
ludovic


Inscrit le: 11 Oct 2010
Messages: 3
Répondre en citant
Merci beaucoup de votre réponse rapide.
J'essayerai dès demain matin. Je vous tiendrai au courant.

Bonne soirée.
Voir le profil de l'utilisateurEnvoyer un message privéEnvoyer un e-mail
ludovic


Inscrit le: 11 Oct 2010
Messages: 3
Répondre en citant
Merci encore. Tout marche très bien maintenant.

Bonne journée
Voir le profil de l'utilisateurEnvoyer un message privéEnvoyer un e-mail
Problème pour imposer un déplacement
Vous ne pouvez pas poster de nouveaux sujets dans ce forum
Vous ne pouvez pas répondre aux sujets dans ce forum
Vous ne pouvez pas éditer vos messages dans ce forum
Vous ne pouvez pas supprimer vos messages dans ce forum
Vous ne pouvez pas voter dans les sondages de ce forum
Vous pouvez joindre des fichiers
Vous pouvez télécharger des fichiers
Toutes les heures sont au format GMT + 2 Heures  
Page 1 sur 1  

  
  
 Répondre au sujet